当前位置:首页 > 单片机 > 单片机
[导读] 作为一个简单实用的示例,图1中的电路利用一个8位PIC微控制器控制一个4位LED显示器,显示出按下了哪个按钮。当任意按钮被按下时,比较器中断程序会立即作出响应。该程序会在VREF值之间进行循环,直至比较器输出COUT

 作为一个简单实用的示例,图1中的电路利用一个8位PIC微控制器控制一个4位LED显示器,显示出按下了哪个按钮。当任意按钮被按下时,比较器中断程序会立即作出响应。该程序会在VREF值之间进行循环,直至比较器输出COUT返回高电平,表明该按钮被按下。完整注释的汇编程序源代码总共不到100字。该代码并未作过度优化,从而可方便理解或易于转化到其他控制器上。

汇编程序源代码:

; MULTIBTN.ASM: sensing upto 15 pushbuttons with one I/O (pin6: GP1/CIN-)

; BENABADJI Noureddine - ORAN - Dec. 11...14th, 2013

;

Errorlevel -302 ; avoid warning #302: Register in operand not in bank0.

; Ensure that bank bits are correct.

List P = 12F683

#include "p12f683.inc"

__CONFIG _INTOSCIO&_MCLRE_OFF&_PWRTE_ON&_WDT_OFF&_FCMEN_OFF&_IESO_OFF&_BOD_ON&_CPD_OFF&_CP_OFF

#define LED1 GPIO, 0 ; output bit0 of the 4-bit binary LED display

#define LED2 GPIO, 2 ; output bit1 of the 4-bit binary LED display

#define LED3 GPIO, 4 ; output bit2 of the 4-bit binary LED display

#define LED4 GPIO, 5 ; output bit3 of the 4-bit binary LED display

;----------------------------- define variables ------------------------------

CBLOCK 0x20 ; bank0 = [0x20...0x7F] = 94 bytes

;delay

cnt1, cnt2, cnt3 ; counters

ENDC

;------------------------------------------------------------------------------

BANK0 macro

BCF STATUS, RP0 ; bank0

endm

;------------------------------------------------------------------------------

BANK1 macro

BSF STATUS, RP0 ; bank1

endm

;------------------------------------------------------------------------------

SIregGEval8b macro file, val, jmpOk ; if (file >= val) goto jmpOk ;

MOVLW val

SUBWF file, w ; w = file - val

BTFSC STATUS, C

GOTO jmpOk ; yes

endm

;/////////////////////////////////////////////////////////////////////////////

; MAIN PROGRAM

;/////////////////////////////////////////////////////////////////////////////

ORG 0x00 ; reset vector

GOTO Setup

ORG 0X04 ; interrupt vector

GOTO IntCmp

;/////////////////////////////////////////////////////////////////////////////

;-----------------------------------------------------------------------------

LEDsOFF

CALL Delay256ms

CLRF GPIO ; all LEDs off

RETLW 0

;-----------------------------------------------------------------------------

Delay256ms

CLRF cnt2

CLRF cnt1

NOP ; 1us

DECFSZ cnt1, f ; 1us

GOTO $-2 ; 2us => 4*256 = 1024 us, approx. 1 ms internal delay loop

DECFSZ cnt2, f ; approx. 256 ms external delay loop

GOTO $-4

RETLW 0

;/////////////////////////////////////////////////////////////////////////////

Setup

BANK1

CLRF TRISIO ; config. all I/O as outputs

BCF OPTION_REG, T0CS ; use pin5 as GP2, not TOCKI

CLRF ANSEL ; use all AN as digital I/O

BANK0

CLRF GPIO ; all LEDs off

MOVLW b'00000111'

MOVWF CMCON0 ;comparator off

splash ; (initial test for LEDs)

BSF LED1

CALL LEDsOFF

BSF LED2

CALL LEDsOFF

BSF LED3

CALL LEDsOFF

BSF LED4

CALL LEDsOFF

;;;;;;;;;;

initializeComparator

BANK1

MOVLW b'00001010' ;config. GP1 as input (will be CIN-)

MOVWF TRISIO

;BANK0

MOVLW b'10100001'

;BANK1

MOVWF VRCON ;Vref on, low range, VR=0001 => ratio = 1/24

BANK0

MOVLW b'00000100'

MOVWF CMCON0 ;comparator on: CIN- = GP1; CIN+ = Vref; Cout internal

;;;;;;;;;

;enable interrupt

BANK1

BSF INTCON, PEIE ; enable interrupt on Comparator trip

BSF PIE1, CMIE ; enable interrupt on Comparator trip

BANK0

BSF INTCON, GIE ; set general interrupt enable

goto $ ; infinite loop (waiting for an interrupt)

;-----------------------------------------------------------------------------

; Comparator trip interrupt routine

;-----------------------------------------------------------------------------

IntCmp

;don't need to save any context, only interrupting a goto $

BANK0

MOVLW .1

MOVWF cnt3

nextBtn

INCF cnt3, F

SIregGEval8b cnt3, .16, whichBtn ; if (cnt3 >= 16) goto whichBtn ;

MOVLW b'10100000'

ADDWF cnt3, W

BANK1

MOVWF VRCON ;Vref on, low range, VR=cnt3

BANK0

BTFSS CMCON0, COUT ; Cout == 1 ?

GOTO nextBtn

whichBtn

DECF cnt3, F

BTFSC cnt3, 0

BSF LED1

BTFSC cnt3, 1

BSF LED2

BTFSC cnt3, 2

BSF LED3

BTFSC cnt3, 3

BSF LED4

CALL LEDsOFF

endIntCmp

MOVLW b'10100001'

BANK1

MOVWF VRCON ;Vref on, low range, VR=0001 => ratio = 1/24

BANK0

BCF PIR1, CMIF ; clear comparator interrupt flag

RETFIE

;-----------------------------------------------------------------------------

END

本站声明: 本文章由作者或相关机构授权发布,目的在于传递更多信息,并不代表本站赞同其观点,本站亦不保证或承诺内容真实性等。需要转载请联系该专栏作者,如若文章内容侵犯您的权益,请及时联系本站删除。
换一批
延伸阅读

从汇编角度来说,如果“test %al, %al”能改成“test %0x1, %al”就没有匪夷所思的问题了,如此一来应该会降低CPU的效率,毕竟执行指令还需要一个立即数,我没搞过编译器也没设计过CPU,纯属瞎猜,能搞...

关键字: 汇编 CPU 编译器

【说在前面的话】其实我很久之前就想写这篇文章了,但彼时总觉得这是一个伪命题:既然已经用了MDK,编译出来的代码,无论是体积还是性能都甩下armgcc好几条街,谁还会想用gcc来进行Cortex-M开发呢?对那些只能使用a...

关键字: GCC MDK 汇编

1.背景群里有个小伙伴学习设计加密方法,如同某商用软件输入注册码后就能使用扩展功能。设计时他很自然的想着所写的加密措施是否足够健壮安全,是否有什么方法可以绕过加密检查,也就是破解。权限管理仅在启动后检查一次注册码是否有效...

关键字: 指令 汇编 软件

最近很多伙计问我现在搞嵌入式还有没有必要学习汇编?

关键字: 嵌入式 汇编

  着眼于可穿戴式电子产品的成长态势,全球各地的实验室不断致力于整合织物(时装的原材料)与电子显示器。许多研究人员们陆续展示各种可改变色彩的织物,但比利时微电子研究中心Imec最近宣称首先在软性

关键字: led显示器 可穿戴设备

在8月7日的中国信息化百人会2020峰会上,华为消费者业务CEO余承东表示,由于美国方面的第二轮制裁,华为手机芯片供应困难,但华为将坚持自研,在半导体方面和终端器件方面加大投入。而余承东此前坦承,美国新一轮打压对准的是华...

关键字: ic芯片 led显示器 华为

来源 :智能软件研究中心,作者:罗宇哲,直接来源:华为开发者社区 声明:本公众号转发仅为传播相关技术知识,不作任何商业用途,如有疑义请联系删除。 01 ARM汇编指令 操作系统中硬件相关的部分集中体现在汇编指令和对寄存器...

关键字: ARM 汇编

Part 1. 机器指令 上一次 我们已经了解了 二进制和 CPU 的基本原理,知道了程序运行时,CPU 每秒数以亿次、十亿次、百亿次地震荡着时钟,同步执行着微小的 「电子操作」,例如:从内存读取一个字节的数据到 CPU...

关键字: 高级编程 编程语言 汇编

来源 :智能软件研究中心,作者:罗宇哲,直接来源:华为开发者社区 声明:本公众号转发仅为传播相关技术知识,不作任何商业用途,如有疑义请联系删除。 01 ARM汇编指令 操作系统中硬件相关的部分集中体现在汇编指令和对寄存器...

关键字: ARM 汇编

北京时间4月30日早间消息,据外媒报道,Facebook首席执行官扎克伯格周三警告称,过早重新开放公共空间“几乎可以肯定”将会导致新冠病毒的继续爆发,并带来不良的经济后果。 扎克伯格在公司第一季度财报

关键字: 扎克伯格 FACEBOOK LTE 汇编
关闭
关闭