当前位置:首页 > 单片机 > 单片机
[导读] 把二进制数转换成 BCD 码,是很常见的,做而论道以前也发表过这样的程序。但是,过去都是用寄存器,如果要求用片内RAM单元,就少见了。当然,也可以把片内RAM单元的数据,先传送到寄存器,再利用以前写

把二进制数转换成 BCD 码,是很常见的,做而论道以前也发表过这样的程序。


但是,过去都是用寄存器,如果要求用片内RAM单元,就少见了。


当然,也可以把片内RAM单元的数据,先传送到寄存器,再利用以前写的程序进行转换。转换完毕后,再把结果传送到片内RAM单元。


如果直接用片内RAM单元来进行转换呢?


这也是可以的,只是速度会慢一些。


以前,从来没有见过有谁编写出来直接使用片内RAM转换的程序。


没有人编写,大概就是速度的原因吧。


做而论道现在就编写一个,大家看看,和使用寄存器相比,速度有多少降低。


下面就是这样的题目。

===============================

编写一段程序,将存放于片内RAM 40H、41H单元中的 16 位二进制数转化为压缩BCD码存放到 38H~3AH 中。

;

TO_BCD:

MOV R2, #16 ;转换16位

CLR A

MOV 38H, A ;先清零

MOV 39H, A

MOV 3AH, A

LOOP:

MOV A, 41H ;取被转换二进制数

RLC A

MOV 41H, A

MOV A, 40H

RLC A ;最高位移动到C

MOV 40H, A

;---------------------

MOV A, 3AH ;取数

ADDC A, 3AH ;左移并加上C

DA A ;转为BCD码

MOV 3AH, A ;保存

MOV A, 39H

ADDC A, 39H

DA A

MOV 39H, A

MOV A, 38H

ADDC A, 38H

MOV 38H, A

DJNZ R2, LOOP ;循环16次

RET


本程序已经经过试验,保证正确。

===============================

下面,是另外一个问题,问的就是相反转换的问题。


这样的程序,做而论道以前就编写出来,并且使用过很多年了。


只是在网上、书上,从来也没有见过这样的转换程序。

----

编写一段程序,将存放于片内 RAM 30H~32H 单元中的5位压缩BCD数(小于65536)转化为二进制数存放到 40H、41H 单元中。



TO_BIN:

MOV A, 32H

SWAP A

ANL A, #0FH ;得到十位数字

MOV B, #10

MUL AB

MOV B, 32H

ANL B, #0FH ;得到个位数字

ADD A, B

MOV 41H, A ;(41H)=十位*10+个位

;---------------------

MOV A, 31H

SWAP A

ANL A, #0FH ;得到千位数字

MOV B, #10

MUL AB

MOV B, 31H

ANL B, #0FH ;得到百位数字

ADD A, B ;(A)=千位*10+百位

MOV B, #100

MUL AB ;(B A)=千位*1000+百位*100

;---------------------

ADD A, 41H

MOV 41H, A

CLR A

ADDC A, B

MOV 40H, A ;(40H 41H)=千位*1000+百位*100+十位*10+个位

;---------------------

MOV A, #10H ;2710H=1万

MOV B, 30H ;万位

MUL AB

MOV R2, B

MOV R3, A

MOV A, #27H

MOV B, 30H ;万位

MUL AB

ADD A, R2

MOV R2, A ;R2 R3=万位*10000

;---------------------

MOV A, R3

ADD A, 41H

MOV 41H, A

MOV A, R2

ADDC A, 40H

MOV 40H, A

RET


本程序已经通过了试验验证,保证正确。



后记:


针对这个问题,提问者采纳了一个错误的程序。


这个错误程序,不仅有错,长度还差不多达到本程序的两倍。


做而论道编写的程序,不仅正确,基本上就是最精简的,大家可以比较看一下。


其实,做而论道还有更为精简的,仅仅才 35 行指令,可以说是世上最精练转换程序。只是技巧太高,不易理解,就不公布了。


用 C 语言编程,不太合乎题目的要求。


但是,也有人编写的很好,收录在下面:


viod BcdHex(viod)

{

unsigned short int *OutAdd, *SrcAdd, x;

SrcAdd = 0x30;

OutAdd = 0x40;


*OutAdd = 0; x = 1;

*OutAdd += (SrcAdd[0] & 0x0F) * x; x *= 10;

*OutAdd += (SrcAdd[0] >> 4) * x; x *= 10;

*OutAdd += (SrcAdd[1] & 0x0F) * x; x *= 10;

*OutAdd += (SrcAdd[1] >> 4) * x; x *= 10;

*OutAdd += (SrcAdd[2] & 0x0F) * x;

}


本站声明: 本文章由作者或相关机构授权发布,目的在于传递更多信息,并不代表本站赞同其观点,本站亦不保证或承诺内容真实性等。需要转载请联系该专栏作者,如若文章内容侵犯您的权益,请及时联系本站删除。
换一批
延伸阅读

8位单片机在嵌入式设计领域已经成为半个多世纪以来的主流选择。尽管嵌入式系统市场日益复杂,8位单片机依然不断发展,积极应对新的挑战和系统需求。如今,Microchip推出的8位PIC®和AVR®单片机系列,配备了先进的独立...

关键字: 单片机 嵌入式 CPU

在嵌入式系统开发中,程序烧录是连接软件设计与硬件实现的关键环节。当前主流的单片机烧录技术已形成ICP(在电路编程)、ISP(在系统编程)、IAP(在应用编程)三大技术体系,分别对应开发调试、量产烧录、远程升级等不同场景。...

关键字: 单片机 ISP ICP IAP 嵌入式系统开发

在嵌入式系统开发中,看门狗(Watchdog Timer, WDT)是保障系统可靠性的核心组件,其初始化时机的选择直接影响系统抗干扰能力和稳定性。本文从硬件架构、软件流程、安全规范三个维度,系统分析看门狗初始化的最佳实践...

关键字: 单片机 看门狗 嵌入式系统

本文中,小编将对单片机予以介绍,如果你想对它的详细情况有所认识,或者想要增进对它的了解程度,不妨请看以下内容哦。

关键字: 单片机 开发板 Keil

随着单片机系统越来越广泛地应用于消费类电子、医疗、工业自动化、智能化仪器仪表、航空航天等各领域,单片机系统面临着电磁干扰(EMI)日益严重的威胁。电磁兼容性(EMC)包含系统的发射和敏感度两方面的问题。

关键字: 单片机 电磁兼容

以下内容中,小编将对单片机的相关内容进行着重介绍和阐述,希望本文能帮您增进对单片机的了解,和小编一起来看看吧。

关键字: 单片机 复位电路

在这篇文章中,小编将为大家带来单片机的相关报道。如果你对本文即将要讲解的内容存在一定兴趣,不妨继续往下阅读哦。

关键字: 单片机 异常复位

今天,小编将在这篇文章中为大家带来单片机的有关报道,通过阅读这篇文章,大家可以对它具备清晰的认识,主要内容如下。

关键字: 单片机 仿真器

单片机将是下述内容的主要介绍对象,通过这篇文章,小编希望大家可以对它的相关情况以及信息有所认识和了解,详细内容如下。

关键字: 单片机 中断 boot

一直以来,单片机都是大家的关注焦点之一。因此针对大家的兴趣点所在,小编将为大家带来单片机的相关介绍,详细内容请看下文。

关键字: 单片机 数字信号 模拟信号
关闭